Alternative zu ws2801 lpd6803 tm.... u.s.w gesucht!

Pesi · 25. Dezember 2011

Einfach mal überlegen, was da nun genau passiert

das untere ist schon "richtiger": wenn YL ungleich low(DMX_Buffer+DMX_Channels) ist, und/oder YH ungleich high(DMX_Buffer+DMX_Channels), dann kann die Zahl insgesamt nicht gleich sein, also geht es weiter mit dem Kopieren etc.

Nur, so wie das da steht, springt er ja direkt wieder darüber - vergleicht also, ist nicht gleich, also wieder nach oben, vergleicht wieder - bis in alle Ewigkeit...

einfach mal überlegen, was bei welcher Bedingung passieren soll, und wo Du dann also hin springen musst... in einem Fall muss eben die Schleife weiter laufen, im anderen ist sie beendet, je nachdem, ob Du nun die Zahl erreicht hast oder nicht...

leddie · 25. Dezember 2011

So?

Code

Bit_LoopL:			;Loop für Low Wert


		cpi	YL, low(DMX_Buffer+DMX_Channels)	; Low Wert vergleichen
		brne 	Bit_LoopL	

Bit_LoopH:			;Loop für High Wert
							; 
		cpi	YH, high(DMX_Buffer+DMX_Channels)	;  High Wert vergleichen
		brne 	Bit_LoopH

Pesi · 25. Dezember 2011

Nee, das ist ja wieder das selbe!

Noch mal zum Grundverständnis: So ein Assembler-Programm ist eine Liste von Befehlen, die der µC stur der Reihe nach abarbeitet - ausser Du sagst ihm eben, dass er an ner bestimmten Stelle weitermachen soll.

Und das kann auch an eine Bedingung geknüpft sein, eben bei "brne" z.B. geht es an der angegebenen Stell weiter, wenn der Vergleich ergeben hat, dass die beiden Register (oder Register und Zahl) nicht gleich sind - wenn sie gleich sind, macht er mit dem nächsten Befehl weiter...

was passiert nun hier..? - Du vergleichst in Zeile 3 YL mit einer Zahl, die sind nicht gleich - also springt er beim "brne" (in Zeile 4) wieder hoch zu Zeile 1, macht also als nächstes wieder den Vergleich...

und da sich an YL ja nix geändert hat (wo auch, wurden ja in der Zwischenzeit keine anderen Befehle ausgeführt) ergibt der Vergleich also natürlich *wieder* "nicht gleich", also wieder hoch zu Zeile 1, usw., bis in alle Ewigkeit... bis zur Zeile 6 kommt er gar nicht!

also, Du hast folgende Bedingungen:

- YL ungleich low(DMX_Buffer+DMX_Channels) -> Schleife weiter machen, ansonsten weiter zum Vergleich von YH

- YH ungleich high(DMX_Buffer+DMX_Channels) -> Schleife weiter machen, ansonsten Schleife beendet

noch mal überlegen, wo Du nun bei welcher Bedingung hin springen muss, und bedenken: *In* der Schleife findet ja auch noch was statt, eben genau das Bitschieben und rumkopieren und Y-Pointer erhöhen... *dafür* machst Du die Schleife ja, nicht als Selbstzweck...

leddie · 25. Dezember 2011

Ach JETZT versteh ich bissl mehr

dieser Y+ unten ist also dafür dass der den Y Wert erhöht. Mann mann.... Dann mach ich das mal jetzt ordentlicher . Danke.

leddie · 25. Dezember 2011

So. Wie siehts denn jetzt aus lieber Meister?

Code

; ================================================================================================
;
; TLC5947 8Bit -> 12Bit Routine V0.001/Ultra Alpha
; Leddie's Prüfungsarbeit, die unter Aufsicht von Pesi geschrieben wird. ;)
;
; ================================================================================================
; benutzte Register  	: temp0-3, ZL, ZH, YL, YH werden gesichert
; gem. benutzte Register : keine
; reservierte Register   : keine
;.
; Definitionen (zum Kopieren):
;
;.equ DMX_Channels	= 24		; Anzahl zu empfangender Kanäle  (max 512)
;.equ DMX_Buffer	= 0x0060	; RAM-Bereich für 8Bit Daten Verarbeitung
;.equ ARR_TLC_Out	= 0x0060	; RAM-Puffer für Ausgabedaten
;


Change_8Bit_to_12Bit:


		push temp0   ; Register sichern (ausleihen)
		push temp1
		push temp2
		push temp3
		push ZH
		push ZL
		push YH
		push YL





		ldi YL, low(DMX_Buffer) 	; Y auf DMX-Buffer
		ldi YH, high(DMX_Buffer)


		ldi ZL, low(Arr_TLC_Out) 	; Z auf Ausgabepuffer
		ldi ZH, high(Arr_TLC_Out)


;Start Kopf der Schleife
Bit_Loop:


		cpi	YL, low(DMX_Buffer+DMX_Channels)	; Low Wert vergleichen
		brne 	Bit_Shift
		cpi	YH, high(DMX_Buffer+DMX_Channels)	;  High Wert vergleichen
		brne 	Bit_Shift
rjmp Bit_Ende

Bit_Shift:
;Ende Kopf der Schleife




		ld temp0, Y+
		clr temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1


		st Z+, temp0 		; Low-Byte speichern
		st Z+, temp1 		; High-Byte speichern




;Start Fuß der Schleife


rjmp Bit_Loop


  
Bit_Ende:						; 12Bit Umwandlung fertig
;Ende Fuß der Schleife


		
		pop YL					; Register wieder herstellen
		pop YH
		pop ZL
		pop ZH
		pop temp3
		pop temp2
		pop temp1
		pop temp0


ret	; Das wars dann wohl - Und tschüss!


; ================================================================================================

Alles anzeigen

Pesi · 25. Dezember 2011

Zitat von leddie

dieser Y+ unten ist also dafür dass der den Y Wert erhöht. Mann mann....

Achso - dachte, das wäre klar, irgendwo muss ja Y erhöht werden, sonst bearbeitest Du ja immer die selbe RAM-Adresse, und die Schleife hört nie auf....

wurde ja hier schon erklärt:

Zitat von Pesi

dann in einer Schleife die Werte kopieren - immer erst den Wert aus dem DMX-Buffer holen mit Post-Increment (bedeutet, der Zeiger zeigt nach dem holen auf das nächste Byte):

ld temp0, Y+

das "Y+" ist eben das post-increment, siehe die schon mehrfach angesprochene Befehlsübersicht...

ja, so funktioniert das nun - ist aber ein bisschen "Spaghetticode"...

Also noch ein bisschen Feinschliff:

Die Schleife muss ja auf jeden Fall mindestens 1x durchlaufen werden - also kannst Du die Abfrage, ob Du schon fertig bist, auch nach unten setzen ("fußgesteuerte Schleife")

Damit wird das Ganze wesentlich übersichtlicher, weil Du läufst dann einfach durch die Bitschieberei, dann kommt die Abfrage, ob alle Bytes durch sind. Wenn nicht, geht's wieder nach oben, wenn ja, dann geht's weiter zum Ende der Routine - ohne das ganze hin- und hergespringe, da wird kein einziger "rjmp" gebraucht....

und die Register temp3 und temp2 brauchst Du ja gar nicht in der Routine, also musst Du die auch nicht sichern - spart auch wieder 4 Anweisungen, also sowohl Platz im Flash, wie auch Zeit bei der Ausführung...

kannst Du ja zur Übung noch machen, und dann ist die Routine perfekt, und hast Du eh' schon einiges gelernt

ist doch gar nicht so schwer, oder...? - wenn man das mit den Schleifen, Sprüngen, Pointern, etc. mal kapiert hat, und die 10, 15 häufigsten Befehle auswendig weiß, und eben genau, *was sie machen*, dann reicht das für 90% aller Programmierfälle... ist in jeder anderen Sprache (dieser Art natürlich, bei objektorientiert wie Java etc. sieht's wieder anders aus, aber das nimmt ja keiner für µC-Programmierung) genauso.

leddie · 26. Dezember 2011

Hi,

Zitat von Pesi

Post-Increment

Den Begriff hatte ich leider nicht so gut verstanden.

Zitat von Pesi

ist aber ein bisschen "Spaghetticode

Yep, hab schon gelesen, zu viele GO TO's (jumps) u.s.w

Zitat von Pesi

Die Schleife muss ja auf jeden Fall mindestens 1x durchlaufen werden - also kannst Du die Abfrage, ob Du schon fertig bist, auch nach unten setzen

Du ohne Witz, daran habe ich auch schon vorhin, vor dein Post gedacht, warum ich da unnötige jumps mache und warum ich das einfach nicht mit BRNE löse. Ist ja auch so ne art jump Funktion.

Zitat von Pesi

und die Register temp3 und temp2 brauchst Du ja gar nicht in der Routine

Stimmt, ich depp!! Warum sind die überhaupt noch da ? Wird ja eh nicht benutzt!

So, wenn ich das so mache wie mein Logik mir es vorschreibt waer die Finale version dann so:

Code

; ================================================================================================
;
; TLC5947 8Bit -> 12Bit Routine V0.001/Ultra Alpha
; Leddie's Prüfungsarbeit, die unter Aufsicht von Pesi geschrieben wird. ;)
;
; ================================================================================================
; benutzte Register  	: temp0-3, ZL, ZH, YL, YH werden gesichert
; gem. benutzte Register : keine
; reservierte Register   : keine
;.
; Definitionen (zum Kopieren):
;
;.equ DMX_Channels	= 24		; Anzahl zu empfangender Kanäle  (max 512)
;.equ DMX_Buffer	= 0x0060	; RAM-Bereich für 8Bit Daten Verarbeitung
;.equ ARR_TLC_Out	= 0x0060	; RAM-Puffer für Ausgabedaten
;


Change_8Bit_to_12Bit:


		push temp0   ; Register sichern (ausleihen)
		push temp1
		push ZH
		push ZL
		push YH
		push YL



		ldi YL, low(DMX_Buffer) 	; Y auf DMX-Buffer
		ldi YH, high(DMX_Buffer)


		ldi ZL, low(Arr_TLC_Out) 	; Z auf Ausgabepuffer
		ldi ZH, high(Arr_TLC_Out)


;Start Kopf der Schleife


Bit_Loop:


		
;Ende Kopf der Schleife




		ld temp0, Y+
		clr temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1
		rol temp0
		rol temp1


		st Z+, temp0 		; Low-Byte speichern
		st Z+, temp1 		; High-Byte speichern




;Start Fuß der Schleife


		cpi	YL, low(DMX_Buffer+DMX_Channels)	; Low Wert vergleichen
		brne 	Bit_Loop
		cpi	YH, high(DMX_Buffer+DMX_Channels)	;  High Wert vergleichen
		brne 	Bit_Loop


;Ende Fuß der Schleife


		
		pop YL					; Register wieder herstellen
		pop YH
		pop ZL
		pop ZH
		pop temp1
		pop temp0


ret	; Das wars dann wohl - Und tschüss!


; ================================================================================================

Alles anzeigen

Wenns Passt, bitte Applaus!!

Pesi · 26. Dezember 2011

*Applaus*

...und Gute Nacht!

leddie · 26. Dezember 2011

YES!!!!

Ein ganz Herzlichen Dank für dein Geduld lieber Pesi. Ohne Deine Hilfe waer das echt nicht Realisierbar für mich.

Noch kurz eine Frage:

Diese Bit Umwandlung ist doch wie ich verstehe nicht echtes 12bit sondern es wandelt nur die 8 bit Werte auf 12bit um aber ausgegeben werden dann doch noch 8 bit qualitaet oder? Also erst mit der mit gamma table kommen glaub ich erst die kompletten 12bit werte ins Spiel? Oder versteh ich das falsch?

Pesi · 26. Dezember 2011

Genau, da werden eben nur die Bits um 4 nach links geschoben, damit Du den kompletten Wertebereich ausnützt (also bei 255 eben ganz hell ist), aber die Auflösung erhöht sich natürlich nicht... es bleibt weiter bei 255 möglichen Helligkeitsstufen

wie gesagt, das ist der Vorteil an diesem "modularen" SW-Aufbau mit Subroutinen, Du kannst dann später mal einfach die Routine "Change_8Bit_to_12Bit" durch eine ersetzen, die in ner Tabelle nachschaut, und hast dann so Deine Gamma-Korrektur drin, ohne sonst an der SW groß umbauen zu müssen...

auch da hast Du dann nur 255 einstellbare Stufen, aber die sind eben anders verteilt, also praktisch ne Teilmenge aus den möglichen 4.096 Stufen des TLC, so dass die Helligkeitsverteilung für's Auge gleichmäßiger ist....

leddie · 26. Dezember 2011

Also über 255 stufen gehts nicht wegen DMX oder?
Na ja, reicht ja eigentlich, mit dem "Gamma Table" sollte ich demnaechst trotzdem die unteren Dimm-Bereiche korrigieren, weil die mich am meistens stören zb bei ws2801'er u.s.w..

Pesi · 26. Dezember 2011

genau, das Problem sind immer die unteren Bereiche, weil es da so "abgestuft" ist - an sich reichen 255 Werte, im oberen Bereich z.B. sieht man zwischen 250 und 254 eh' keinen Unterschied mehr - das wird mit der Gamma-Tabelle eben "entzerrt", so dass der Helligkeitszuwachs immer gleich ist, es also z.B. von 5 auf 6 eben um "das selbe Stück heller wird" wie von 230 auf 231...

Pesi · 30. Dezember 2011

Naa, ist hier schon was weiter gegangen...? - Eigentlich hast Du's ja, DMX-Empfangsroutine, Umsortierroutine, Ausgaberoutine, musst Du ja nur noch zusammensetzen...

wenn's dann läuft, hätte ich noch ne einfache Gammakorrektur für Dich....

übrigens, wegen den WS2811, von denen hier auch mal die Rede war: habe nun solche Pixel da, und sie laufen auf Anhieb mit der TM1804-Ausgabroutine... Timing ist zwar lt. Datenblatt etwas unterschiedlich, aber anscheinend nicht so kritisch...

das ist wohl wirklich als Alternative zum TM1804 von nem anderen Hersteller gedacht (Chinesen kupfern ja auch untereinander gerne ab), Pinbelegung ist auch exakt die selbe...

leddie · 30. Dezember 2011

Ja, geht schon, aber im Moment Sylvester-Stress!!!!

Nach Sylvester werd ich mich wieder drauf Konzentrieren. Klar, fast alles ist schon fertig. Und mit der einfachen Gamma von Dir ist es natürlich Oberklasse!!! Spart Zeit und Nerven

Das mit ws2811 und tm1804 ist echt lustig. Dann haben wir ja damit kein stress auch die ws2811 zu Steuern Heisst: We are ready for the future

EDIT:
Fast vergessen: Ein guten Rutsch & FROHES NEUES JAHR!!! Hoffe Ihr feiert auch ordentlich

leddie · 8. Januar 2012

Ich warte jetzt nur noch auf die 5947 Samples. Leider kommen die erst in 2 Wochen. ...

leddie · 19. Januar 2012

TI Samples sind da! Werd mal demnaechts langsam versuchen die klitzekleinen Teile zu löten

leddie · 22. Januar 2012

hat jemand vielleicht ne Eagle lbr für den TLC5947? Waer Toll!

vincent81 · 16. Februar 2012

ich bestelle vermutlich noch in dieser Woche ein paar Rollen mit einzeln adressierbaren RGB-LEDs mit dem WS2801 Controller mit 32 RGB-LEDs/m.I paid 95 euros Für 5m http://www.bestlightingbuy.com…ssable-rgb-led-strip.html

leddie · 25. Februar 2012

Hi Pesi,

Habe mal den TLC5947 ausprobiert, irgendwie wollen die leds nicht

Unten mal die configuration.inc Datei. Waere das so richtig?

Code

; ************************************************************************************************
; * DMX zu TLC5947													 	 *
; * Konfigurationen																	 			 *
; ************************************************************************************************


; ================================================================================================
; Ports I/O setzen etc.
; ------------------------------------------------------------------------------------------------


		ldi		temp0, (1<<TLC_Data) | (1<<TLC_Clk) | (1<<TLC_Blank) | (1<<TLC_Lat)	; TLC5947-Ports auf Ausgang
		out		TLC_DDR, temp0


		sbi		S_LED_DDR, S_LED				; Port für Status-LED auf Ausgang
		cbi		S_LED_Port, S_LED				; Status-LED an


; ================================================================================================
; Stackpointer setzen
; ------------------------------------------------------------------------------------------------


		ldi 	temp0, HIGH(RAMEND)				; HIGH-Byte der obersten RAM-Adresse
		out 	SPH, temp0						; in den Stackpointer
		ldi 	temp0, LOW(RAMEND)				; LOW-Byte der obersten RAM-Adresse
		out 	SPL, temp0						; in den Stackpointer


; ================================================================================================
; USART konfigurieren für DMX
; ------------------------------------------------------------------------------------------------


	   	ldi 	temp0, UBRR_DMX			 		; Usart auf Baudrate DMX setzen
		out 	UBRRL, temp0
		clr 	temp0
		out 	UBRRH, temp0


		ldi 	temp0, (3<<UCSZ0) |	(1<<URSEL)	; 8 Datenbits, 1 Stoppbit
		out 	UCSRC, temp0			
		sbi		UCSRB, TXEN						; Transmitter enable
		sbi 	UCSRB, RXEN						; Receiver enable
		sbi 	UCSRB, RXCIE					; RX Complete Int. enable


		clr		DMX_state						; Start-Status: auf Frame Error warten


; ================================================================================================
; DMX-Startadresse setzen
; ------------------------------------------------------------------------------------------------


		ldi		temp0, high(DMX_Adress)
		mov		DMX_Base_H, temp0
		ldi		temp0, low(DMX_Adress)
		mov		DMX_Base_L, temp0


; ================================================================================================
; Farbreihenfolge setzen
; ------------------------------------------------------------------------------------------------


		ldi		temp0, RGB_change
		sts		RGB_Order, temp0


; ================================================================================================


		sei										; Interrupts aktivieren


; ================================================================================================

Alles anzeigen

Pesi · 25. Februar 2012

Im Prinzip ja, wenn Du diese Konstanten, also TLC_Data usw. richtig definiert hast...

weil wenn da irgendwo (Bei mir ist das immer in ner extra Datei "Definitions.inc") z.B. drin steht

.equ TLC_DDR = DDRC
.equ TLC_Data = 0

Du aber die Datenleitung an Port A 3 hast, dann funktioniert das natürlich nicht...

ansonsten sind da natürlich noch mehr Stellen in der SW, wo irgendwas nicht passen kann, also ggfs. dann mal den *ganzen* Code posten (am Besten als .zip-Anhang)

wegen Deiner PN: fertiges .hex-File für Rainbow habe ich nicht - Du kannst ja einfach mal die Ausgaberoutine aufrufen, nach dem Reset ist das RAM mit zufälligen Werten gefüllt, also irgendwas müssten die LEDs dann anzeigen...

Alternative zu ws2801 lpd6803 tm.... u.s.w gesucht!

Teilen

Benutzer online in diesem Thema